xl9555_backlight.ino

Go to the documentation of this file.

 
#include <IoExpanderDrv.hpp>
#include <AW9364LedDriver.hpp>
 
#ifdef ENABLE_TFT
#include "TFT_eSPI.h"
TFT_eSPI tft;
#endif
 
#ifndef SENSOR_SDA
#define SENSOR_SDA  17
#endif
 
#ifndef SENSOR_SCL
#define SENSOR_SCL  18
#endif
 
#ifndef SENSOR_IRQ
#define SENSOR_IRQ  -1
#endif
 
// Drive LED  pin, corresponding to XL9555 GPIO2
#define BACKLIGHT_PIN   2
 
IoExpanderXL9555 expander;
AW9364LedDriver ledDriver;
uint8_t level = 0;
 
void setup()
{
    Serial.begin(115200);
 
    // Set the interrupt input to input pull-up
    if (SENSOR_IRQ > 0) {
        pinMode(SENSOR_IRQ, INPUT_PULLUP);
    }
 
#ifdef ENABLE_TFT
    tft.begin();
    tft.setRotation(1);
    tft.fillScreen(TFT_GREEN);
#endif
 
    /*
    *
    *    If the device address is not known, the 0xFF parameter can be passed in.
    *
    *    XL9555_UNKNOWN_ADDRESS  = 0xFF
    *
    *    If the device address is known, the device address is given
    *
    *    XL9555_SLAVE_ADDRESS0  = 0x20
    *    XL9555_SLAVE_ADDRESS1  = 0x21
    *    XL9555_SLAVE_ADDRESS2  = 0x22
    *    XL9555_SLAVE_ADDRESS3  = 0x23
    *    XL9555_SLAVE_ADDRESS4  = 0x24
    *    XL9555_SLAVE_ADDRESS5  = 0x25
    *    XL9555_SLAVE_ADDRESS6  = 0x26
    *    XL9555_SLAVE_ADDRESS7  = 0x27
    */
    const uint8_t chip_address = XL9555_UNKNOWN_ADDRESS;
 
    if (!expander.begin(Wire, chip_address, SENSOR_SDA, SENSOR_SCL)) {
        while (1) {
            Serial.println("Failed to find XL9555 - check your wiring!");
            delay(1000);
        }
    }
 
    ledDriver.begin(expander, BACKLIGHT_PIN);
 
}
 
void loop()
{
    // 16 dimming levels
    Serial.print("level:");
    Serial.println(level);
    ledDriver.setBrightness(level);
    level++;
    level %= MAX_BRIGHTNESS_STEPS;
    delay(1000);
}