bma423_step_detector.ino

Go to the documentation of this file.

 
#include <AccelerometerDrv.hpp>
 
#ifndef SENSOR_SDA
#define SENSOR_SDA  21
#endif
 
#ifndef SENSOR_SCL
#define SENSOR_SCL  22
#endif
 
#ifndef SENSOR_IRQ
#define SENSOR_IRQ  39
#endif
 
SensorBMA423 accelSensor;
 
volatile bool isInterruptTriggered = false;
 
void onStepDetected()
{
    Serial.println("Step detected");
}
 
void onStepCount(uint32_t stepCount)
{
    Serial.print("Step count: ");
    Serial.println(stepCount);
}
 
void setup()
{
    bool rslt;
 
    Serial.begin(115200);
    while (!Serial);
 
    pinMode(SENSOR_IRQ, INPUT);
    attachInterrupt(SENSOR_IRQ, +[]() {
        isInterruptTriggered = true;
    }, RISING);
 
    // Sensor initialization
    rslt = accelSensor.begin(Wire, BMA4XX_I2C_ADDR_SDO_HIGH, SENSOR_SDA, SENSOR_SCL);
    if (!rslt) {
        while (1) {
            Serial.println("BMA4xx sensor initialization failed");
            delay(1000);
        }
    }
 
    Serial.print(accelSensor.getModelName());
    Serial.println(" Sensor initialized successfully");
 
    // Set sensor orientation, based on the hardware placement setting
    rslt = accelSensor.setRemapAxes(SensorRemap::TOP_LAYER_RIGHT_CORNER);
    if (!rslt) {
        Serial.println("Failed to set remap axes");
    }
 
    // Accelerometer configuration
    // The desired operation mode. Allowed values are SUSPEND, NORMAL.
    OperationMode operationMode = OperationMode::NORMAL;
    // The desired full-scale range. Allowed values are FS_2G, FS_4G, FS_8G, FS_16G.
    AccelFullScaleRange fullScaleRange = AccelFullScaleRange::FS_2G;
    // The desired bandwidth. Allowed values are OSR4_AVG1, OSR2_AVG2, NORMAL_AVG4, etc.
    AccelBandwidth bandwidth = AccelBandwidth::OSR2_AVG2;
    // The desired data rate in Hz. Allowed values are 0.78, 1.56, 3.12, 6.25, 12.5, 25, 50, 100, 200, 400, 800, 1600.
    float data_rate_hz = 100.0f;
    // The desired performance mode. Allowed values are CIC_AVG_MODE, CONTINUOUS_MODE
    AccelPerfMode perfMode = AccelPerfMode::CIC_AVG_MODE;
 
    if (!accelSensor.configAccelerometer(operationMode, fullScaleRange, data_rate_hz, bandwidth, perfMode)) {
        Serial.println("Failed to configure accelerometer");
        while (1);
    }
 
    bool feature_enable = true; // Enable feature
    bool interrupt_enable = true;   //True: hardware interrupt enabled
    InterruptPinMap pin_map = InterruptPinMap::PIN1;
    bool reset_counter = true; // True: reset step counter on new activity
    /* Setting watermark level 1, the output step resolution is 20 steps.
     * Eg: 1 means, 1 * 20 = 20. Every 20 steps once output triggers
     */
    uint16_t step_counter_wm = 1;
 
    rslt = accelSensor.setInterruptPinConfig(
               pin_map, // Which pin should the hardware interrupt be routed to?
               false,   // level trigger
               false,   // active high
               true,    // output enable
               false);  // input disable
    if (!rslt) {
        Serial.println("Failed to set interrupt pin configuration");
        while (1);
    }
 
    // Enable step counter feature
    rslt = accelSensor.enableStepCounter(feature_enable, step_counter_wm, reset_counter);
    if (!rslt) {
        Serial.println("Failed to enable step counter");
        while (1);
    }
 
    // Enable step detector feature
    rslt = accelSensor.enableStepDetector(feature_enable, interrupt_enable, pin_map);
    if (!rslt) {
        Serial.println("Failed to enable step detector");
        while (1);
    }
 
    // Set step count callback
    accelSensor.setOnStepCountCallback(onStepCount);
 
    // Set step detected callback
    accelSensor.setOnStepDetectedCallback(onStepDetected);
 
    delay(3000);
 
    Serial.println("Now you can move the sensor.");
}
 
void loop()
{
    if (isInterruptTriggered) {
        isInterruptTriggered = false;
        accelSensor.update();
    }
    delay(30);
}